Question

Координаты двух полей шахматной доски заданы в виде двух пар чисел x1 y1 и x2 y2 на первом поле стоит ферзь,на втором-конь.определить,бьет ферзь коня,конь ферзя,или фигуру не угрожают друг другу.

Answer 1

Function Knight(x1, y1, x2, y2: integer): Boolean;
{ Возвращает True, если возможен переход с (x1,y1) на (x2,y2) }
begin
  if abs(x2 - x1) = 2 then Knight := (abs(y2 - y1) = 1)
  else
  if abs(x2 - x1) = 1 then Knight := (abs(y2 - y1) = 2)
  else Knight := false
end;

function Queen(x1, y1, x2, y2: integer): Boolean;
{ Возвращает True, если возможен переход с (x1,y1) на (x2,y2) }
begin
  Queen := (x1 = x2) or (y1 = y2) or (abs(x2 - x1) = abs(y2 - y1))
end;

var
  xk, yk, xq, yq: integer;

begin
  Write('Укажите через пробел координаты коня  [1..8]: ');
  Readln(xk, yk);
  Write('Укажите через пробел координаты ферзя [1..8]: ');
  Readln(xq, yq);
  if Knight(xk, yk, xq, yq) then Writeln('Конь бьет ферзя')
  else
    if Queen(xq, yq, xk, yk) then Writeln('Ферзь бьет коня')
    else Writeln('Фигуры не угрожают друг другу')
end.

Примеры выполнения программы:

Укажите через пробел координаты коня  [1..8]: 3 5
Укажите через пробел координаты ферзя [1..8]: 1 7
Ферзь бьет коня

Укажите через пробел координаты коня  [1..8]: 3 5
Укажите через пробел координаты ферзя [1..8]: 7 7
Фигуры не угрожают друг другу

Укажите через пробел координаты коня  [1..8]: 4 3
Укажите через пробел координаты ферзя [1..8]: 5 5
Конь бьет ферзя