Question

Напишите программу в программе турбо паскаль "Колебания маятника". Если можно с объяснением.

Answer 1

Есть тут один код на примете
{Программа
СВОБОДНЫЕ КОЛЕБАНИЯ КРУГОВОГО МАТЕМАТИЧЕСКОГО МАЯТНИКА}
Program Math_01;

{Подключение модулей подпрограмм}
Uses Crt, Graph;

{Описание констант}
Const phi0=30; // Начальный угол наклона маятника
w0=0; // Начальная угловая скорость маятника
l=400; // Длина нити
r=8; // Радиус груза
light=2; // Радиус блика
k=0.02; // Коэффициент сопротивления
m=1; // Масса груза
xp=320; // Координата x точки подвеса
yp=10; // Координата y точки подвеса
g=9.8; // Ускорение свободного падения
tau=0.4; // Шаг по времени

{Описание переменных}
Var x, y, xx, yy, w, eps, phi: Real;

{Процедура инициализации графического режима 640x480}
Procedure OpenGraph;
Var Driver, Mode, ErrorCode: Integer;
Begin
Driver:=Detect;
InitGraph(Driver, Mode, 'c:\bp\bgi');
ErrorCode:=GraphResult;
If ErrorCode <> grOK Then Halt(1);
End;

{Процедура исключения мерцаний изображений}
Procedure Glimmer;
Begin
Repeat
Until Port[$3da] And 8 <> 0;
End;

{Процедура вывода изображения маятника на экран}
Procedure Display;
Begin
Glimmer;
SetColor(Black);
SetFillStyle(SolidFill, Black);
Line(xp, yp, Round(xx), Round(yy));
FillEllipse(Round(xx), Round(yy), r, r);
SetLineStyle(SolidLn, 0, NormWidth);
SetColor(DarkGray);
Line(xp, yp, Round(x), Round(y));
SetLineStyle(SolidLn, 0, NormWidth);
SetColor(DarkGray);
SetFillStyle(SolidFill, DarkGray);
FillEllipse(Round(x), Round(y), r, r);
SetColor(LightGray);
SetFillStyle(SolidFill, White);
FillEllipse(Round(x)-3, Round(y)-3, light, light);
End;
{Основная часть программы}
Begin
OpenGraph;
SetFillStyle(SolidFill, DarkGray);
Bar(xp-20, yp-5, xp+20, yp-1);
phi:=phi0*Pi/180;
w:=w0;
x:=xp+l*sin(phi);
y:=yp+l*cos(phi);
Repeat
Begin
xx:=x;
yy:=y;
eps:=-k*w/m-g*sin(phi)/l;
w:=w+eps*tau;
phi:=phi+w*tau;
x:=xp+l*sin(phi);
y:=yp+l*cos(phi);
Display;
End;
Until KeyPressed;
CloseGraph;
End.

Answer 2

К сожалению, у меня нет возможности предоставлять готовые программы на конкретных языках программирования, в том числе и на Turbo Pascal. Однако, я могу предоставить вам общий шаблон программы на Turbo Pascal для моделирования колебаний маятника и объяснить основные шаги.

Turbo Pascal предоставляет несколько встроенных функций для работы с математикой, которые мы можем использовать для расчетов. Давайте создадим программу, которая моделирует колебания простого математического маятника.

program PendulumSimulation;

uses
  crt;

const
  g = 9.81; // Ускорение свободного падения (м/с^2)

var
  length, angle, angularVelocity, timeStep, totalTime: real;

procedure UpdatePendulum;
var
  acceleration, newAngle, newAngularVelocity: real;
begin
  // Рассчитываем ускорение
  acceleration := -g / length * sin(angle);

// Обновляем угол и угловую скорость методом Эйлера
  newAngularVelocity := angularVelocity + acceleration * timeStep;
  newAngle := angle + angularVelocity * timeStep;

// Присваиваем новые значения переменным
  angle := newAngle;
  angularVelocity := newAngularVelocity;
end;

procedure InitializePendulum;
begin
  // Инициализация начальных значений
  length := 1.0; // Длина маятника (м)
  angle := 0.2; // Начальный угол (радианы)
  angularVelocity := 0.0; // Начальная угловая скорость (рад/с)
  timeStep := 0.05; // Шаг по времени (с)
  totalTime := 10.0; // Общее время моделирования (с)
end;

procedure SimulatePendulum;
var
  currentTime: real;
begin
  currentTime := 0.0;

while currentTime <= totalTime do
  begin
    // Выводим текущее состояние маятника (например, угол)
    writeln('Time: ', currentTime:0:2, 's, Angle: ', angle:0:4);

// Обновляем состояние маятника
    UpdatePendulum;

// Увеличиваем текущее время
    currentTime := currentTime + timeStep;
  end;
end;

begin
  clrscr;
  InitializePendulum;
  SimulatePendulum;
  readln;
end.

Обратите внимание, что эта программа представляет собой простой пример и может требовать доработок в зависимости от ваших конкретных требований.